# Maintainer: Jari Vetoniemi <mailRoxas@gmail.com>

pkgname=pndmanager-bzar
pkgver=1.3.11
pkgrel=1
pkgtitle="PNDManager"
pkgdesc="Package manager for PND repositories"
license=('CCPL:sa')
url="https://github.com/bzar/panorama"
depends=('qt4-dev' 'pandora-libpnd' 'gcc-linaro-4.7')
source=('git+git://github.com/bzar/panorama.git')

pndexec=('scripts/panorama.sh')
pndicon=('icon.png')

prepare() {
  cd panorama
  git submodule update --init --recursive
}

build() {
  cmake -DCMAKE_INSTALL_PREFIX=/usr -DLIBPNDMAN_BUILD_STATIC=ON panorama
  make
}

pnd_build() {
  cmake -DLIBPNDMAN_NO_SYSTEM_LIBS=ON -DCMAKE_INSTALL_PREFIX=/ -DLIBPNDMAN_BUILD_STATIC=ON -DPANDORA=ON panorama
  make
}

package() {
  make DESTDIR="$pkgdir" install

  # cleanup useless interface files
  find "$pkgdir/interfaces/" -mindepth 1 -maxdepth 1 -type d -not -name 'PNDManager' -exec rm -r {} \;
}

pnd_post_package() {
  # not installed as executable in CMakeLists.txt
  chmod +x "$pkgdir/run.sh"

  # copy libraries makepnd can't detect as Pandora default distro has similar named libs
  # but they are in fact too old versions
  install -d "$pkgdir/lib"
  install -m755 /usr/local/lib/libstdc++.so.6 "$pkgdir/lib/" # HACK: dchrt contains newer binutils and gcc in /usr/local/
  install -m755 /usr/lib/libQt{Core,Gui,Network,Script,Sql,Svg}.so.4 "$pkgdir/lib/"
  install -m644 "$srcdir/panorama/contrib/pndmanager/icon.png" "$pkgdir/"
  install -d "$pkgdir/plugins/imageformats"
  install -m755 /usr/lib/qt4/plugins/imageformats/libq{gif,jpeg,svg,ico,mng,tiff}.so "$pkgdir/plugins/imageformats"
  install -d "$pkgdir/previews"
  install -m644 "$srcdir/panorama/contrib/pndmanager/previews/preview-"{1,2,3,4,5}.png "$pkgdir/previews"
  install -d "$pkgdir/scripts"
  install -m755 "$srcdir/panorama/contrib/pndmanager/scripts/panorama.sh" "$pkgdir/scripts"

}

pnd_application_information() {
  pndauthor='B-ZaR'
  pndappdata='pndmanager'
  pndcategory=('Settings/PackageManager')
  pndscreenshot=('previews/preview-1.png' 'previews/preview-2.png' 'previews/preview-3.png' 'previews/preview-4.png' 'previews/preview-5.png')
}

md5sums=('SKIP')

# vim: set ts=8 sw=2 tw=0 ft=sh syn=sh :